自動計算の設定

=SUM({score1}, {score2}, {score3})

={score}
={first.total_score}
={employee.hire_date}

={score} * 1.5
={total} + 100
=ROUND({average}, 2)

=IF({score}>=80, "合格", "不合格")
=IF({grade}="A", 100, 0)
="値: ""{特殊な値}""" → 値: "特殊な値"

=IF(TRUE, "常に表示", "表示されない")
=NOT(FALSE)
=AND(TRUE, {isActive})

=DATEDIF("2024-04-01", TODAY(), "M")
=DATEDIF(DATE(2024, 4, 1), TODAY(), "M")

=({a} + {b}) * {c}  → aとbを足してからcを掛ける
={a} + {b} * {c}    → bとcを掛けてからaを足す

=SUM({field1}, {field2}, {field3})
=SUM(10, 20, 30)  → 60

=AVERAGE({score1}, {score2})
=AVERAGE(80, 90, 70)  → 80

=MIN({評価1}, {評価2}, {評価3})
=MIN(5, 2, 8)  → 2

=MAX({評価1}, {評価2}, {評価3})
=MAX(5, 2, 8)  → 8

=MEDIAN({評価1}, {評価2}, {評価3})
=MEDIAN(1, 2, 3, 4, 5)  → 3
=MEDIAN(1, 2, 3, 4)  → 2.5

=STDEV({評価1}, {評価2}, {評価3})

=COUNT({評価1}, {評価2}, {評価3})

=COUNTA({評価1}, {評価2}, {評価3})

=SUMIF([first.rank], "S", [first.raiseAmount])  → ランクがSの対象者の昇給金額合計

=AVERAGEIF([first.rank], "A", [first.score])  → ランクがAの対象者のスコア平均

=COUNTIF([first.rank], "S")  → ランクがSの対象者の数

=PERCENTRANK([first.performanceScore], {first.performanceScore})  → 対象者のスコアがグループ内で何パーセンタイルか

=RANK({first.score}, [first.score])    → 降順（スコアが高い方が1位）
=RANK({first.score}, [first.score], 1) → 昇順（スコアが低い方が1位）

=ROUND(3.456, 2)   → 3.46
=ROUND(3.456)      → 3
=ROUND(1234, -2)   → 1200

=ROUNDUP(3.141, 2)   → 3.15
=ROUNDUP(-3.141, 2)  → -3.15

=ROUNDDOWN(3.789, 2)   → 3.78
=ROUNDDOWN(-3.789, 2)  → -3.78

=ABS(-5)  → 5
=ABS(3)   → 3

=MOD(10, 3)   → 1
=MOD(10, -3)  → -2
=MOD(-10, 3)  → 2

=IF({score}>=80, "合格", "不合格")
=IF({評価}>3, {評価}*1.1, {評価})
=IF({isComplete}, "完了")

=IFS({score}>=90, "S", {score}>=80, "A", {score}>=70, "B", {score}>=60, "C", TRUE, "D")
=IFS({評価}==5, "最優秀", {評価}==4, "優秀", {評価}==3, "良好", TRUE, "要改善")

=NOT(TRUE)  → FALSE
=NOT({score}<50)  → スコアが50以上ならTRUE

=IF(AND({score1}>=60, {score2}>=60), "両方合格", "再試験")

=IF(OR({score1}>=80, {score2}>=80), "優秀", "標準")

=SWITCH({grade}, "S", 100, "A", 80, "B", 60, 0)
=SWITCH({評価}, 5, "最優秀", 4, "優秀", 3, "良好", "要改善")

=ISBLANK({comment})  → commentが未入力ならTRUE
=IF(ISBLANK({score}), "未評価", {score})  → スコアが未入力なら"未評価"、入力済みならスコアを返す

=ISNUMBER({score})  → scoreが数値ならTRUE
=IF(ISNUMBER({評価}), {評価} * 10, 0)  → 評価が数値なら10倍、それ以外は0

=ISTEXT({comment})  → commentがテキストならTRUE
=IF(ISTEXT({grade}), SWITCH({grade}, "S", 100, "A", 80, 0), {grade})

=ISLOGICAL({isActive})  → isActiveが論理値ならTRUE
=IF(ISLOGICAL({flag}), {flag}, FALSE)

=CONCATENATE("結果: ", {score})  → "結果: 85"
=CONCATENATE({lastName}, " ", {firstName})  → "田中 太郎"
=CONCATENATE("評価: ", {rating}, "点")  → "評価: 4.5点"

=TODAY()  → "2025-01-16"

=DATE(2024, 4, 1)  → "2024-04-01"

=DATEDIF({employee.hire_date}, TODAY(), "Y")  → 勤続満年数
=DATEDIF({employee.hire_date}, TODAY(), "M")  → 勤続満月数
=DATEDIF("2023-04-15", "2025-12-19", "Y")  → 2

=YEAR({employee.hire_date})  → 2020

=MONTH(TODAY())  → 1

=DAY({employee.hire_date})  → 15

=DAYS(TODAY(), {employee.hire_date})  → 入社からの経過日数

={score}
={field1} + {field2}

={first.total_score}
={second.rating}

1. score1（数値入力）
2. score2（数値入力）
3. subtotal（自動計算）: =SUM({score1}, {score2})
4. bonus（自動計算）: ={subtotal} * 0.1
5. total（自動計算）: ={subtotal} + {bonus}

=DATEDIF({employee.hire_date}, TODAY(), "Y")  → 勤続年数

=SWITCH({employee.job_key}, "engineer", 1.2, "designer", 1.1, "sales", 1.0, 1.0)
=IF({employee.job_category_key} = "management", {score} + 10, {score})

=SWITCH({employee.grade_key}, "M1", 1.2, "M2", 1.1, "S1", 1.0, "S2", 0.9, 1.0)
=IF({employee.grade_group_key} = "management", {score} + 10, {score})

={employee.supplemental_metric.sublevel}
=IF({employee.supplemental_metric.sublevel} >= 3, 1.1, 1.0)

={employee.compensation.base_salary}  → 現在の基本給
={new_base_salary} - {employee.compensation.base_salary}  → 昇給額
={employee.compensation.base_salary} * 12 + {employee.compensation.bonus}  → 年収

={employee.salary_band.base_salary_min}
=({employee.salary_band.base_salary_min} + {employee.salary_band.base_salary_max}) / 2  → 中央値
=IF(AND({employee.compensation.base_salary} >= {employee.salary_band.base_salary_min}, {employee.compensation.base_salary} <= {employee.salary_band.base_salary_max}), "レンジ内", "レンジ外")

# スコアの合計
=SUM({score1}, {score2}, {score3})

# スコアの平均
=AVERAGE({score1}, {score2}, {score3})

# スコアの平均を小数第1位で四捨五入
=ROUND(AVERAGE({score1}, {score2}, {score3}), 1)

# 加重平均
=({score1} * 0.3 + {score2} * 0.5 + {score3} * 0.2)

# 80点以上なら"合格"、未満なら"不合格"
=IF({score}>=80, "合格", "不合格")

# スコアに応じたランク付け
=IFS({score}>=90, "S", {score}>=80, "A", {score}>=70, "B", {score}>=60, "C", TRUE, "D")

# 等級に応じた係数
=SWITCH({employee.grade_key}, "M1", 1.2, "M2", 1.1, "S1", 1.0, "S2", 0.9, 1.0)

# 勤続満年数
=DATEDIF({employee.hire_date}, TODAY(), "Y")

# 勤続年月を文字列で表示
=CONCATENATE(DATEDIF({employee.hire_date}, TODAY(), "Y"), "年", DATEDIF({employee.hire_date}, TODAY(), "YM"), "ヶ月")

# 勤続3年以上なら評価に補正
=IF(DATEDIF({employee.hire_date}, TODAY(), "Y") >= 3, {score} * 1.1, {score})

# 昇給額
={new_base_salary} - {employee.compensation.base_salary}

# 昇給率（パーセント）
=({new_base_salary} / {employee.compensation.base_salary} - 1) * 100

# 年収の計算
={employee.compensation.base_salary} * 12 + {employee.compensation.bonus}

# 給与レンジの中央値
=({employee.salary_band.base_salary_min} + {employee.salary_band.base_salary_max}) / 2

# コンパレシオ（給与レンジ内での位置）
=({employee.compensation.base_salary} - {employee.salary_band.base_salary_min}) / ({employee.salary_band.base_salary_max} - {employee.salary_band.base_salary_min}) * 100

# 等級と勤続年数を組み合わせた評価係数
=IF(AND({employee.grade_group_key} = "management", DATEDIF({employee.hire_date}, TODAY(), "Y") >= 5), 1.3, 1.0)

# 前フェーズのスコアを参照した最終スコア
=ROUND(({first.total_score} * 0.3 + {second.total_score} * 0.7), 1)

# 結果の文字列表示
=CONCATENATE({employee.grade_key}, " (", {score}, "点): ", IF({score}>=80, "合格", "不合格"))